A new tool for humanitarian engineering

An article about a DIY corn sheller was superseded in just 2 years. Engineeringforchange.org posted the second article two years after the first article was released in 2012. The new design involves a short segment of English-like code you can learn before finish reading this Post. In contrast, the first article is essentially a construction manual which requires more handicraft skill to build.

What makes this case special is not the quick appearance of an entirely new method, nor the coincidence. It is the simplicity of the new approach. Though Linked-in posts are supposed to pass ideas and inspiration, I would like to attempt here explain the method as well as the complete sheller CAD design and let you see for yourself if it is really that simple.

You may follow the link to read the old approach for curiosity while I shall explain the new approach. It uses 3D-printer to output the corn sheller tool and the CAD (computer aided design) software used is the open-source free software called OpenSCAD. Unlike most CAD software, this one is text based, meaning that you create your design like writing a program describing how it is constructed. Its beauty is that we don’t need to learn another user interface. Another beauty is the ease of making changes, and enable others to easily see the differences by either explicit comments or automated comparison software.

First, download the software and install it depending on whether it is a PC, Mac, or Linux computer. This CAD software is only about 20MB ! If you want to try it on a smartphone, the Android equivalent is called ScorchCAD.

Now, we have the CAD software installed. Thanks to Joshua Pearce of Michigan Tech's Laboratory in Open Sustainability and Technology, we can freely use and modify the corn sheller code, which we did make some changes to make it read more like English. Start OpenSCAD and copy-paste the following code to the editor pane on the left, press F5 to compile it and get the 3D corn sheller image instantly. If you have difficulty in getting this done, ask a friend or your kids for help.

------------------------------------------------------------------------------------------

// First, determine the dimensions
h=55;// height of corn sheller
rt=35; rb=0.85*rt;// top and bottom radius
d=6; r=1.5; //number of digits and digit front radius
l=0; // extra length of digit
t=5; // thickness of sheller
$fn=60; //draw circle as polygon

module sheller(){
  union (){ // a sheller consists of d digits and a wall
    // fingers are arranged in a ring
    for (z = [1:d]) rotate([0,0, z*360/d]) translate([rb,0, h*.1]) finger();
    difference(){ // the circular wall is tapered
      cylinder(h =h, r1 =rt, r2 =rb, center=true);
      translate([0,0,0])cylinder(h =h+1, r1 =rt-t, r2 =rb-t, center=true);
}}}

module finger(){
  rotate([0,atan((rt-rb)/h)*-1.5,0]) // fingers are inclined a bit more than the wall
  hull() //created by wrapping around following
  { // 2 parallel rods of radius r and 2r
    cylinder(h = h*.9, r1 =2*r, r2 =2*r, center=true);
    translate([-(t+l),0,0]) cylinder(h = h*.9, r1 =r, r2 =r, center=true);
}}

rotate([180,0,0])
difference(){ // clean up by chopping part of fingers extending beyond the bottom
  sheller();
  translate([0,0,h/2]) cylinder(h=10, r=rt+10);
}

------------------------------------------------------------------------------------------

Now let’s return to read the design in more detail. You can add a double slash “//” in the beginning of any line you don’t understand and see how the image changes. It can also be understood more easily if we just combine the main comments. Here is the English version of the corn sheller design:-

First, determine the dimensions. The module "sheller" says a sheller consists of d digits and a wall and fingers are arranged in a ring. The circular wall is tapered. The module "finger" says fingers are inclined a bit more than the wall, created by wrapping around 2 parallel rods of radius r and 2r. Clean up by chopping part of fingers extending beyond the bottom to get the sheller.

To get the 3D-printed sheller, select the “Export as STL” icon and you have an STL file which can be 3D-printed. That’s all. If you want different sizes, just change the parameters near the top of this code segment.

Pass the design to your friends by having them copy-paste it from above and see how many can get the design into their computer/smartphone and how many can also understand the design. Send them the English version if they find it difficult. I have tried with my friends. More than a few can understand it in a few minutes, and quite a number of them are NOT technical people.

By the way, one very effective way to pass short codes like this is to send it as a WhatsApp (or other instant messaging platform) message. Our design team find exchanging short code segments alongside instant messaging discussions quite effective to improve on a design as a team.

Now we are done! With 3D CAD design getting so much easier than before and 3D printer everywhere, endless possibilities are before us. I hope you find this “Brief introduction to 3D design with OpenSCAD for humanitarian engineering” useful and apply it in your future work to serve communities in need.